Blogini // Digitaalinen arkisto

Olen nyt muuttanut NixOS-kotipalvelimeni varmuuskopioinnin ja siirtynyt yksinkertaisesta päivittäisestä skriptistä tuntikohtaiseen varmuuskopiointiin. Ei aivan yhtä tyylikästä kuin ystäväni hallinnoimalla Mastodon-instanssilla – siellä meillä on ZFS-snapshot 20 minuutin välein – mutta olen tyytyväinen tähänkin ratkaisuun. Ja täytyy sanoa, että NixOS miellyttää minua yhä enemmän. Ilman tekoälyä se olisi kuitenkin aivan liian monimutkaista ymmärrettäväksi, mutta nykyään osaan ainakin lukea valmiita Nix-tiedostoja. Harkitsin joskus palvelimen vaihtamista tavalliseen Linuxiin, mutta niin kauan kuin tämä toimii näin hyvin...

1. /etc/nixos: Koko NixOS-konfiguraatio (kaikki .nix-tiedostot).

2. /opt/minecraft: Kaikki Minecraft-palvelimen maailmat ja tiedot.

3. /opt/satisfactory: Satisfactory-palvelimen tallennukset ja konfiguraatio.

4. /opt/Blog: Blogin lähdekoodi ja sisällöt.

5. /opt/ui: Mastodon-käyttöliittymän tiedostot.

6. /opt/audiobookshelf: Äänikirjat ja niihin liittyvä tietokanta.

Kaikki tämä päätyy S3-tallennustilaan, joka on liitetty RClonen kautta.

NixOS-konfiguraatio

{ config, pkgs, ... }:

{
  # BorgBackup-konfiguraatio
  services.borgbackup.jobs.hourly = {
    # Polku repositoryyn S3-liitoksessa
    repo = "/opt/S3/Backup/NixOSHomeServer_Borg";

    # Salasanaa ei vaadita
    encryption.mode = "none";

    # Pakkaus säästää vielä enemmän tilaa
    compression = "auto,zstd";

    # Varmuuskopioitavat polut
    paths = [
      "/etc/nixos"
      "/opt/minecraft"
      "/opt/satisfactory"
      "/opt/Blog"
      "/opt/ui"
      "/opt/audiobookshelf"
    ];

    # Tuntikohtainen suoritus
    startAt = "hourly";

    # Alusta repository automaattisesti, jos se puuttuu
    doInit = true;

    # Säilytyssäännöt (Pruning)
    prune.keep = {
      within = "1d"; # Kaikki snapshotit viimeisen 24 tunnin ajalta
      daily = 7;
      weekly = 4;
      monthly = 12;
    };
  };

  # Varmistetaan, että S3-liitos on valmis ennen kuin Borg käynnistyy
  systemd.services.borgbackup-job-hourly = {
    requires = [ "rclone-s3-mount.service" ];
    after = [ "rclone-s3-mount.service" ];
  };
}

Asensin itselleni oman blogin — ennen kaikkea oppiakseni tuntemaan #NixOS:n paremmin. Yllättäen kaikki sujui melko mutkattomasti.

WriteFreely sopii tähän tarkoitukseen todella hyvin: se on minimalistinen, nopea ottaa käyttöön ja vailla turhaa painolastia. Täydellinen tapa aloittaa ja oppia samalla jotain uutta. Konfiguraatio on miellyttävän selkeä. Muutama asetus kohdilleen, hakemiston valmistelu, käänteinen välityspalvelin eteen — ja valmista tuli.

Tältä näyttää nykyinen NixOS-konfiguraationi sitä varten:

{ config, pkgs, ... }:

{
  services.writefreely = {
    enable = true;
    host = "blog.burningboard.org"; 
    settings = {
      server = {
        port = 8080;
        min_log_level = "debug";
      };
      app = {
        host = "https://blog.burningboard.org";
        single_user = true;
        landing = "/read";
        wf_modesty = true;
        federation = true;
        public_stats = true;
        theme = "write";
      };
    };
    stateDir = "/opt/writefreely";
  };

  # Korjaus ActivityPub-avainten luontiin: federaatio vaatii openssl:n
  systemd.services.writefreely.path = [ pkgs.openssl ];

  # Datahakemiston automaattinen luonti oikeilla käyttöoikeuksilla
  systemd.tmpfiles.rules = [
    "d /opt/writefreely 0700 writefreely writefreely -"
  ];

  services.caddy.virtualHosts."blog.burningboard.org".extraConfig = ''
    reverse_proxy 127.0.0.1:8080 {
      header_up Host {host}
      header_up X-Real-IP {remote_host}
      header_up X-Forwarded-For {remote_host}
      header_up X-Forwarded-Proto {scheme}
    }
  '';
}

Siinä se oikeastaan olikin. NixOS tekee tällaisten palveluiden siististä konfiguroinnista ja toistettavuudesta todella helppoa.