Мій блог // Цифровий архів

Я перевів резервне копіювання свого домашнього сервера на NixOS зі звичайного щоденного скрипта на погодинний режим. Це не так елегантно, як на інстансі Mastodon, яким керує мій друг — там ми робимо ZFS-снапшоти кожні 20 хвилин — але цим рішенням я також задоволений. І мушу сказати, що NixOS подобається мені все більше. Без ШІ це було б занадто складно для мого розуміння, але зараз я принаймні можу читати готові Nix-файли. Якось я думав перевести сервер на звичайний Linux, але поки все так добре працює...

1. /etc/nixos: Вся конфігурація NixOS (усі .nix файли).

2. /opt/minecraft: Усі світи та дані сервера Minecraft.

3. /opt/satisfactory: Збереження та конфігурація сервера Satisfactory.

4. /opt/Blog: Вихідний код та вміст блогу.

5. /opt/ui: Файли інтерфейсу Mastodon.

6. /opt/audiobookshelf: Аудіокниги та відповідна база даних.

Усе це потрапляє в S3-сховище, змонтоване через RClone.

Конфігурація NixOS

{ config, pkgs, ... }:

{
  # Конфігурація BorgBackup
  services.borgbackup.jobs.hourly = {
    # Шлях до репозиторію в S3-монтуванні
    repo = "/opt/S3/Backup/NixOSHomeServer_Borg";

    # Пароль не потрібен
    encryption.mode = "none";

    # Стиснення для ще більшої економії місця
    compression = "auto,zstd";

    # Шляхи для резервного копіювання
    paths = [
      "/etc/nixos"
      "/opt/minecraft"
      "/opt/satisfactory"
      "/opt/Blog"
      "/opt/ui"
      "/opt/audiobookshelf"
    ];

    # Погодинне виконання
    startAt = "hourly";

    # Автоматично ініціалізувати репозиторій, якщо він відсутній
    doInit = true;

    # Правила зберігання (Pruning)
    prune.keep = {
      within = "1d"; # Усі снапшоти за останні 24 години
      daily = 7;
      weekly = 4;
      monthly = 12;
    };
  };

  # Переконатися, що S3-монтування готове перед запуском Borg
  systemd.services.borgbackup-job-hourly = {
    requires = [ "rclone-s3-mount.service" ];
    after = [ "rclone-s3-mount.service" ];
  };
}

Я створив власний блог — перш за все для того, щоб краще познайомитися з #NixOS. На мій подив, усе пройшло досить просто.

WriteFreely чудово для цього підходить: мінімалістичний, швидкий у налаштуванні та без зайвого баласту. Ідеально, щоб просто почати й попутно чогось навчитися. Конфігурація приємно лаконічна. Кілька опцій, підготовка директорії, реверс-проксі — і готово.

Ось як виглядає моя поточна конфігурація NixOS для цього:

{ config, pkgs, ... }:

{
  services.writefreely = {
    enable = true;
    host = "blog.burningboard.org"; 
    settings = {
      server = {
        port = 8080;
        min_log_level = "debug";
      };
      app = {
        host = "https://blog.burningboard.org";
        single_user = true;
        landing = "/read";
        wf_modesty = true;
        federation = true;
        public_stats = true;
        theme = "write";
      };
    };
    stateDir = "/opt/writefreely";
  };

  # Виправлення для генерації ключів ActivityPub: федерація потребує openssl
  systemd.services.writefreely.path = [ pkgs.openssl ];

  # Автоматичне створення директорії даних із правильними правами доступу
  systemd.tmpfiles.rules = [
    "d /opt/writefreely 0700 writefreely writefreely -"
  ];

  services.caddy.virtualHosts."blog.burningboard.org".extraConfig = ''
    reverse_proxy 127.0.0.1:8080 {
      header_up Host {host}
      header_up X-Real-IP {remote_host}
      header_up X-Forwarded-For {remote_host}
      header_up X-Forwarded-Proto {scheme}
    }
  '';
}

Ось, власне, і все. NixOS дійсно дозволяє легко та чисто налаштовувати такі сервіси, зберігаючи їх відтворюваність.